INSIGHT

情報・インサイト

HOME

情報・インサイト

WindowsバッチでCSVのファイル名を先頭項目に追加して1ファイルに統合する方法

2020.07.31

Windowsバッチで効率化

前回のWindowsバッチを使って複数ファイルを１つに統合する方法をご紹介しましたが、
今回はその方法を応用し、統合する各ファイル名をCSVの先頭項目に追加しつつ、
１つのファイルにまとめる方法をご紹介します。

バラバラのファイルをまとめて集計したいけど、１つずつ集計するのは大変な作業です。
そんな悩みを一瞬で解決できる方法ですので是非お試しください。

作成ファイルのイメージ

学年の成績データをサンプルに説明します。
フォーマットが共通のCSVデータであれば、商品データ、受発注データ、ログファイルなど、
どんなデータでも応用ができます。

統合するCSV

このようなクラスごとに成績データを1つのファイルにまとめます。
データにクラス名が無いため、このまま統合すると何年何組かわからなくなります。
そこでファイル名（ここではクラス名）を先頭に付けてまとめます。

■1-A.csv（1年A組の試験成績） 1年A組.csv
・・・
■2-A.csv（2年A組の試験成績） 2年A組.csv
・・・
■3-B.csv（3年B組の試験成績） 3年B組.csv

統合ファイル

統合されるファイルはこのようになります。
ファイル名が先頭に追加されたCSVにまとめられます。

■matome.csv
統合イメージ

ファイルは記事の下からダウンロードできるようにしています。

Windowsバッチでファイル統合

それではやってみましょう。

Windowsバッチの作成（ソースのコピペ）

まずはファイルをまとめるためのBATファイルを作ります。
ソースをコピペして「matome.bat」で保存してください。
保存場所はまとめるファイルが配置されているフォルダです。

@echo off
setlocal enabledelayedexpansion
cd /d %~dp0
rem ファイルの文字コードがUTF-8の場合は設定
rem chcp 65001

rem ヘッダーを判定するための行カウント
set /a cnt=0

rem ファイル名を設定
set FILE_NAME=matome.csv

rem フォルダにあるCSVファイルを１つずつ処理
for /f %%a in ('dir /b *.csv') do (
    set TARGET_FILE=%%a
    
    rem ファイル名を出力
    echo TARGET_FILE=!TARGET_FILE!

    rem 1ファイル目であればヘッダーを出力
    if !cnt!==0 (
        rem 1行目を取得して出力
        set /p header=<!TARGET_FILE!
        echo ファイル名,!header!>>"!FILE_NAME!"
    )
    
    rem カウントを追加
    set /a cnt=!cnt!+1
    
    rem ファイルの1行目を飛ばして1行ずつ出力
    for /f "usebackq delims= skip=1" %%b in ("!TARGET_FILE!") do (
       echo !TARGET_FILE!,%%b>>"!FILE_NAME!"
    )
)

endlocal

ポイント

CSVファイル、batファイルはShift-JISを前提にしています
CSVファイルがUTF-8の場合は「rem chcp 65001」のremを削除してください
「echo ファイル名,!header!>>"!FILE_NAME!"」箇所が統合ファイルのヘッダー部分です
【ファイル名】部分を任意の文字（クラス名）など変更して利用してください

　
作成後のイメージはこんな感じです。

Windowsバッチイメージ